Delphi dicas

Controlando display lcd 16x2

{Considere um display LCD de 16 caracteres por 2 linhas previamente conectado a porta paralela.



Obs.: Obviamente não se trata de como construir tal periférico, pois se trata de técnicas de eletrônica e podem ser pesquisados em outros fóruns da categoria.



Primeiro crie a seguinte unit que será a classe de controle do LCD:

}



unit HD44780;



interface



uses

SysUtils, Windows;



const



LCD_EN         = $01;//                              00000001

LCD_EN_I       = LCD_EN xor $FF;

LCD_RS         = $04;//                              00000100

LCD_RS_I       = LCD_RS xor $FF;

LCD_BL         = $08;//                              00001000

LCD_BL_I       = LCD_BL xor $FF;

LCD_LCD3         = $02;//                            00010000

LCD_LCD3_I       = LCD_LCD3 xor $FF;

// Comandos:

LCD_LIMPA      = $01;  // Limpa o Display                           00000001



LCD_HOME       = $02;  // Coloca o cursor na 1. linha e 1. coluna   00000010



LCD_MODO       = $04;  // Modo de Funcionamento:                    00000100

LCD_MODO_M     = $01;  // Mensagem desloca con cursor ou não        00000001

LCD_MODO_C     = $02;  // Cursor desloca para direita, ou esquerda  00000010



LCD_ONOFF      = $08;  // Controle do display:                      00001000

LCD_ONOFF_CP   = $01;  // Cursor piscante ou não                    00000001

LCD_ONOFF_C    = $02;  // Liga cursor ou não                        00000010

LCD_ONOFF_D    = $04;  // Liga Display ou não                       00000100



LCD_DESLOCA    = $10;  // Deslocamento do Cursor:                   00010000

LCD_DESLOCA_D  = $04;  // Desloca pra direita ou esquerda           00000100

LCD_DESLOCA_M  = $08;  // Deslocar Mensagem ou o cursor             00001000



LCD_FUNCAO     = $20;  // Modo de Utilização:                       00100000

LCD_FUNCAO_M   = $04;  // Usar Matriz 5x10 ou 5x7                   00000100

LCD_FUNCAO_L   = $08;  // 2 ou mais linhas ou 1 linha               00001000

LCD_FUNCAO_B   = $10;  // 8 bits ou 4 bits                          00010000



LCD_CGRAM      = $40;  // Estabelece endereço da CGRAM              01000000



LCD_DDRAM      = $80;  // Estabelece endereço da DDRAM              10000000



// Temporizações:

TEMPO_CURTO    = 40;    // 40us

TEMPO_LONGO    = 1600;  // 1600 us

TEMPO_INICIO   = 15000; // 15 ms



type

        THD44780 = class

        private

        ValorPorta2 : Byte;

        public

        PortaLCD : Integer;

        lcd_id : integer;

        Colunas  : Integer;

        Linhas   : Integer;



        procedure IniciaLCD;

        procedure LimpaDisplay;

        procedure Backlight(Ligar : Boolean);

        procedure PosCursor(X, Y : Integer);

        procedure Cursor_Display(CursorLigado, DisplayLigado, CursorPiscante : Boolean);

        procedure DirecaoCursor(PraDireita, MensagemDesloca : Boolean);

        procedure DeslocaCursor_Mensagem(Cursor, PraDireita : Boolean);

        procedure EscreveTexto(Mensagem : String);



        procedure MandaComando(Comando : Byte);

        procedure MandaDados(Dado : Byte);



        constructor Create;

        destructor  Destroy; override;

end;



procedure WritePort(PortValue : Word; DataValue : Byte);

function  ReadPort(PortValue : Word) : Byte;

procedure usleep(Tempo_us : LongInt);



implementation



function inportb(EndPorta: Integer): BYTE stdcall; external 'inpout32.DLL' name 'Inp32';

procedure outportb(EndPorta: integer; Valor:BYTE); stdcall; external 'inpout32.DLL' name 'Out32';





procedure WritePort(PortValue : Word; DataValue : Byte);

begin

        outportb(portvalue, datavalue);

end;



function ReadPort(PortValue : Word) : Byte;

var

ReadData : Byte;

begin

        asm

                Mov dx,PortValue

                In al,dx

                Mov ReadData,al

        end;

        Result := ReadData;

end;



procedure usleep(Tempo_us : LongInt);

var

tempo       : Int64;

ultimotempo : Int64;

perf_freq   : Int64;

diferenca   : LongInt;

begin

        QueryPerformanceFrequency(perf_freq);

        perf_freq := perf_freq div 1000000;

        QueryPerformanceCounter(tempo);

        ultimotempo := tempo;

        while True do begin

                QueryPerformanceCounter(tempo);

                diferenca := tempo - ultimotempo;

                diferenca := diferenca div perf_freq;

                if (diferenca >= Tempo_us) then Break;

        end;

end;



constructor THD44780.Create;

begin

        PortaLCD := $0378;

        ValorPorta2 := $00;

        Colunas := 16;

        Linhas := 2;

        lcd_id := 4;

        WritePort(PortaLCD, 0);

        WritePort(PortaLCD + 1, 0);

        WritePort(PortaLCD + 2, ValorPorta2);

end;



destructor THD44780.Destroy;

begin

        inherited Destroy;

end;



procedure THD44780.MandaComando(Comando : Byte);

begin

        ValorPorta2 := (ValorPorta2) and LCD_RS_I;

        WritePort(PortaLCD + 2, ValorPorta2 and LCD_EN_I);

        WritePort(PortaLCD + 2, ValorPorta2 and LCD_EN_I);

        usleep(1);

        WritePort(PortaLCD, Comando);

        usleep(1);

        WritePort(PortaLCD + 2, ValorPorta2 or LCD_EN);

        if (Comando = LCD_LIMPA) or (Comando = LCD_HOME) then

        usleep(TEMPO_LONGO)

        else

        usleep(TEMPO_CURTO);

end;



procedure THD44780.MandaDados(Dado : Byte);

begin

        ValorPorta2 := (ValorPorta2) or LCD_RS;

        WritePort(PortaLCD + 2, ValorPorta2 and LCD_EN_I);

        usleep(1);

        WritePort(PortaLCD, Dado);

        usleep(1);

        WritePort(PortaLCD + 2, ValorPorta2 or LCD_EN);

        usleep(TEMPO_CURTO);

end;



procedure THD44780.IniciaLCD;

begin

        MandaComando(LCD_FUNCAO or LCD_FUNCAO_B or LCD_FUNCAO_L);

        usleep(TEMPO_INICIO);

        MandaComando(LCD_FUNCAO or LCD_FUNCAO_B or LCD_FUNCAO_L);

        usleep(TEMPO_INICIO);

end;



procedure THD44780.LimpaDisplay;

begin

        MandaComando(LCD_LIMPA);

end;



procedure THD44780.Backlight(Ligar : Boolean);

begin

        //

end;



procedure THD44780.PosCursor(X, Y : Integer);

var

offset : Integer;

begin

        offset := 0;

        if X > Colunas then begin

                X := 1;

                inc(Y);

        end;

        if Y > Linhas then

        Y := 1;

        case Y of

        1: offset := 0;

        2: offset := 64;

        3: offset := 20;

        4: offset := 84;

end;

MandaComando(LCD_DDRAM + offset + (X-1));

end;



procedure THD44780.Cursor_Display(CursorLigado, DisplayLigado, CursorPiscante : Boolean);

var

Temp : Byte;

begin

        Temp := LCD_ONOFF;

        if CursorLigado then Temp := Temp or LCD_ONOFF_C;

        if DisplayLigado then Temp := Temp or LCD_ONOFF_D;

        if CursorPiscante then Temp := Temp or LCD_ONOFF_CP;

        MandaComando(Temp);

end;



procedure THD44780.DirecaoCursor(PraDireita, MensagemDesloca : Boolean);

var

Temp : Byte;

begin

        Temp := LCD_MODO;

        if PraDireita then Temp := Temp or LCD_MODO_C;

        if MensagemDesloca then Temp := Temp or LCD_MODO_M;

        MandaComando(Temp);

end;



procedure THD44780.DeslocaCursor_Mensagem(Cursor, PraDireita : Boolean);

var

Temp : Byte;

begin

        Temp := LCD_DESLOCA;

        if not Cursor then Temp := Temp or LCD_DESLOCA_M;

        if PraDireita then Temp := Temp or LCD_DESLOCA_D;

        MandaComando(Temp);

end;



procedure THD44780.EscreveTexto(Mensagem : String);

var

I : Byte;

begin

        for I := 1 to Length(Mensagem) do

        MandaDados(Ord(Mensagem[I]));

end;



end.



//:::::::::: Exemplo de utilização ::::::::::



unit U_Lcd;



interface



uses

Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

Dialogs, StdCtrls, HD44780;



type

        TNewCharSet = array [0 .. 7] of Byte;

        type

                TForm1 = class(TForm)

                Button1: TButton;

                Button2: TButton;

                Edit1: TEdit;

                Button3: TButton;

                procedure FormCreate(Sender: TObject);

                procedure FormClose(Sender: TObject; var Action: TCloseAction);

                procedure Button1Click(Sender: TObject);

                procedure Button2Click(Sender: TObject);

                procedure Button3Click(Sender: TObject);

                private

                lcd : THD44780;

                public

                Procedure InicializaLCD;

                procedure gerachar(caractere:integer; linha1, linha2, linha3, linha4, linha5, linha6, linha7, linha8:string);

                procedure DefineNewChar(CharNum: Byte; ACharSet: TNewCharSet);

                function BinToInt(Value: String): Integer;

        end;



        var

        Form1: TForm1;



        implementation



        {$R *.dfm}



        procedure TForm1.gerachar(caractere:integer;linha1,linha2,linha3,linha4,linha5,linha6,linha7,linha8:string);

        var

        grafico: TNewCharSet;

        begin

                grafico[0] := bintoint(linha1);

                grafico[1] := bintoint(linha2);

                grafico[2] := bintoint(linha3);

                grafico[3] := bintoint(linha4);

                grafico[4] := bintoint(linha5);

                grafico[5] := bintoint(linha6);

                grafico[6] := bintoint(linha7);

                grafico[7] := bintoint(linha8);

                DefineNewChar(caractere, grafico);

        end;



        procedure TForm1.DefineNewChar(CharNum: Byte; ACharSet: TNewCharSet);

        var

        CGRam: Integer;

        i: Integer;

        begin

                if CharNum > 7 then

                Exit; // can only define from char 0 to 7

                CGRam := $40 + (CharNum shl 3);

                lcd.MandaComando(cgram);

                //WriteControl(CGRam);     //comentar novamente

                for i := 0 to 7 do

                lcd.MandaDados(ACharSet[i]);

                //WriteData(ACharSet[i]); //comentar novamente

        end;



        function TForm1.BinToInt(Value: String): Integer;

        var

        i,Size: Integer;

        begin

                Result:=0;

                Size:=Length(Value);

                for i:=Size downto 1 do

                if Value[i]='1' then Result:=Result+(1 shl (Size-i));

        end;



        procedure TForm1.FormCreate(Sender: TObject);

        begin

                lcd := THD44780.Create;

                InicializaLCD;

        end;



        procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);

        begin

                lcd.Free;

        end;



        procedure TForm1.InicializaLCD;

        begin

                lcd.Colunas := 16;

                lcd.Linhas := 2;

                lcd.IniciaLCD;

                lcd.LimpaDisplay;

        end;



        procedure TForm1.Button1Click(Sender: TObject);

        begin

                gerachar(0,

                '00000',

                '00100',

                '01110',

                '11111',

                '00100',

                '00100',

                '00100',

                '00000');

                lcd.PosCursor(1,1);

                lcd.EscreveTexto(char(0));

        end;



        procedure TForm1.Button2Click(Sender: TObject);

        begin

                lcd.Cursor_Display(false,true,false);

                lcd.PosCursor(1,1);

                lcd.EscreveTexto(Edit1.Text);

                Edit1.SetFocus;

        end;

        procedure TForm1.Button3Click(Sender: TObject);

        begin

                lcd.LimpaDisplay;

        end;



end.